寻找附近的人组队脚本(乞丐版)

西伯利亚的忠犬

RT
[@Login]
#act
MOV L$人物职业中文描述 [战士,法师,道士]

[@CustomButtonClick]

#IF
EQUAL <$CustomButtonID> 21
#ACT
#CALL [QF脚本\自定按钮\综合服务附近组队.txt] @开始附近的人组队



[@开始附近的人组队]
{
#IF
#ACT
MOV S$请求人附近人物名称变量 []
MOV S$请求人附近人物职业变量 []
MOV S$请求人附近人物等级变量 []
MOV S$组队界面内容
MOV N$附近待组队人物数量 0
GOTOLABEL 7 @_@获取附近所有人物数据(<$USERNAME>) 10

#IF
NOT EQUAL S$请求人附近人物名称变量 []
#ACT
MOV L$请求人附近人物名称数组 <$STR(S$请求人附近人物名称变量)>
MOV L$请求人附近人物职业数组 <$STR(S$请求人附近人物职业变量)>
MOV L$请求人附近人物等级数组 <$STR(S$请求人附近人物等级变量)>
MOV N$组队界面循环标识 0
MOV N$组队界面容器初始编号 2
GetListVarCount L$请求人附近人物职业数组 N$附近待组队人物数量
LOOPGOTO @_@构造附近待组队人物界面内容 <$STR(N$附近待组队人物数量)>

#IF
LARGE N$附近待组队人物数量 8
#ACT
MOV S$组队界面LV容器内容 <&ListView:~#L1:19:118:273:136:1:0:0:0:0:0:84:85:9:10:11:6:7:8:12:13:14>
#ELSEACT
MOV S$组队界面LV容器内容 <&ListView:~#L1:19:118:273:136:1:0>

#IF
#ACT
OPENMERCHANTBIGDLG $NewUI1.pak$ 385 1 4 -200 0 1 270 65
#SAY
<&Text:组队系统:120:65{FCOLOR=249;FSIZE=12;FNAME=楷体}>
<&Text:刷新名单:60:263{FCOLOR=251}/@刷新附近玩家名单>
<&Text:玩家姓名:70:98{FCOLOR=70}>
<&Text:职业:170:98{FCOLOR=70}>
<&Text:等级:217:98{FCOLOR=70}>
<&Text:操作:257:98{FCOLOR=70}>
<$STR(S$组队界面LV容器内容)>
<$STR(S$组队界面内容)>

[@_@构造附近待组队人物界面内容]
#IF
#ACT
MOV S$本次循环组队人物名称 <$STR(L$请求人附近人物名称数组[<$STR(N$组队界面循环标识)>])>
TEXTLENGTH <$STR(S$本次循环组队人物名称)> N$本次循环组队人员名称长度
DIV N$本次循环组队人员名称长度 2
INC N$本次循环组队人员名称长度 12
SETSTRINGBLANK S$本次循环组队人物名称 <$STR(N$本次循环组队人员名称长度)> 0
INC S$组队界面内容 <&Layout:#L1~#L<$STR(N$组队界面容器初始编号)>:0:0:273:15>
INC S$组队界面内容 <&text:#L<$STR(N$组队界面容器初始编号)>~:<$STR(S$本次循环组队人物名称)>:0:0{FCOLOR=251}>
INC S$组队界面内容 <&text:#L<$STR(N$组队界面容器初始编号)>~:<$STR(L$请求人附近人物职业数组[<$STR(N$组队界面循环标识)>])>:150:0{FCOLOR=253}>
INC S$组队界面内容 <&text:#L<$STR(N$组队界面容器初始编号)>~:<$STR(L$请求人附近人物等级数组[<$STR(N$组队界面循环标识)>])>:200:0{FCOLOR=250}>
INC S$组队界面内容 <&text:#L<$STR(N$组队界面容器初始编号)>~:组:237:0{FCOLOR=251}/@邀请组队(<$STR(L$请求人附近人物名称数组[<$STR(N$组队界面循环标识)>])>)>
INC N$组队界面循环标识 1
INC N$组队界面容器初始编号 1

[@_@获取附近所有人物数据]
#IF
;CHECKGROUPMEMBERCOUNT < 1
CHECK [7] 0
#ACT
MOV S$发起人姓名 <$SCRIPTPARAM1>
GetHumVar <$STR(S$发起人姓名)> <$STR(S$请求人附近人物名称变量)> S$响应人物名称变量
GetHumVar <$STR(S$发起人姓名)> <$STR(S$请求人附近人物职业变量)> S$响应人物职业变量
GetHumVar <$STR(S$发起人姓名)> <$STR(S$请求人附近人物等级变量)> S$响应人物等级变量
MOV L$响应人获取人物名称变量数组 <$STR(S$响应人物名称变量)>
MOV L$响应人获取人物职业变量数组 <$STR(S$响应人物职业变量)>
MOV L$响应人获取人物等级变量数组 <$STR(S$响应人物等级变量)>
INC L$响应人获取人物名称变量数组 <$USERNAME>
INC L$响应人获取人物职业变量数组 <$STR(L$人物职业中文描述[<$JOB>])>
INC L$响应人获取人物等级变量数组 <$LEVEL>
SetHumVar <$STR(S$发起人姓名)> S$请求人附近人物名称变量 <$STR(L$响应人获取人物名称变量数组)>
SetHumVar <$STR(S$发起人姓名)> S$请求人附近人物职业变量 <$STR(L$响应人获取人物职业变量数组)>
SetHumVar <$STR(S$发起人姓名)> S$请求人附近人物等级变量 <$STR(L$响应人获取人物等级变量数组)>

[@刷新附近玩家名单]
#ACT
GOTO @开始附近的人组队

[@邀请组队]
#IF
#ACT
MOV S$待邀请人物名称 <$SCRIPTPARAM1>

#IF
<$STR(S$待邀请人物名称)>.CHECKGROUPMEMBERCOUNT > 1
#ACT
SENDMSG 6 【<$STR(S$待邀请人物名称)>】已经有队伍了！
BREAK

#IF
<$STR(S$待邀请人物名称)>.CHECK [7] 1
#ACT
SENDMSG 6 【<$STR(S$待邀请人物名称)>】不允许组队邀请！
BREAK

#IF
CHECKGROUPMEMBERCOUNT > 9
#ACT
SENDMSG 6 你的队伍已经满员了！
BREAK

#IF
NOT CheckOnline <$STR(S$待邀请人物名称)>
#ACT
SENDMSG 6 【<$STR(S$待邀请人物名称)>】不在线！
BREAK

#IF
#ACT
MESSAGEBOX 你已经向【<$STR(S$待邀请人物名称)>】发起组队要求\请耐心等待对方回应......
SetHumVar <$STR(S$待邀请人物名称)> S$邀请组队人物姓名 <$USERNAME>
<$STR(S$待邀请人物名称)>.MESSAGEBOX 玩家【<$STR(S$邀请组队人物姓名)>】邀请你组队,是否答应？ @确定开始组队 @拒绝组队邀请

[@确定开始组队]
#IF
CHECKGROUPMEMBERCOUNT > 1
#ACT
SENDMSG 6 你已经有队伍了！
SetHumVar <$STR(S$邀请组队人物姓名)> S$邀请人反馈 <$USERNAME>
<$STR(S$邀请组队人物姓名)>.SENDMSG 6 【<$STR(S$邀请人反馈)>】已经有队伍了！
BREAK

#IF
<$STR(S$邀请组队人物姓名)>.CHECKGROUPMEMBERCOUNT > 9
#ACT
SENDMSG 6 【<$STR(S$邀请组队人物姓名)>】的队伍已经满员！
SetHumVar <$STR(S$邀请组队人物姓名)> S$邀请人反馈 <$USERNAME>
<$STR(S$邀请组队人物姓名)>.SENDMSG 6 你的队伍已经满员，【<$STR(S$邀请人反馈)>】无法再加入了！
BREAK

#IF
#ACT
SetHumVar <$STR(S$邀请组队人物姓名)> S$邀请人反馈 <$USERNAME>
<$STR(S$邀请组队人物姓名)>.CreatGroup <$STR(S$邀请人反馈)>

[@拒绝组队邀请]
#ACT
SetHumVar <$STR(S$邀请组队人物姓名)> S$邀请人反馈 <$USERNAME>
<$STR(S$邀请组队人物姓名)>.SENDMSG 6 【<$STR(S$邀请人反馈)>】拒绝了你的邀请！
}



效果图：







验证不是那么严谨的，不过反正是白嫖的，有什么关系呢？需要的自取。
进度条素材来自于16周年端的ui_common.wzl

文件名称:素材.rar 
下载次数:76  文件大小:9.49 KB 
下载权限: 不限     [金币获取]      [掉链举报] 

安全检测，请放心下载

KFC

狗哥牛B！！！！！！！！！！！！！！！！！！！！！！！！

汤团先生

狗哥牛B！

ldwz

非常不错的代码~~~

cq5388309

狗哥牛逼

呆呆哥

狗哥牛B！！！！！！！！！！！！！！！！！！！！！！！！

气质征服尼玛

狗哥牛B 能分享下哪个怪物改名词缀吗？

c247462443

狗哥牛B！！！！！！！！！！！！！！！！！！！！！！！！

wtw120

狗哥牛B克拉斯！！！！！！！！！！！！！！！！！！！！！！！！

huaye0512

狗哥,**,请收下我的膝盖....................................